Seis Sigma - CyTA

Conjunto de bloques de instrucciones y de objetos de control que realizan una función o tarea. Se divide en módulos.

Módulo:

Formulario:

Ventanas que sirven de interfaz de la aplicación. Contiene controles, eventos, declaraciones de variables y procedimientos.

Estándar:

Clase:

Procedimiento:

Conjunto de instrucciones que forman el código. Pueden ser subrutinas o funciones.

Objeto:

Combinación de código y datos que se pueden tratar como una unidad, por ejemplo, un control, un formulario o un componente de una aplicación

Colección:

Una colección es un objeto que contiene varios objetos que normalmente, pero no siempre, son del mismo tipo.

En Microsoft Excel, por ejemplo, el objeto Workbooks contiene todos los objetos Workbook abiertos.

Evento:

Código que se ejecuta cada vez que se realiza una acción sobre un objeto: clic, doble clic, arrastrar, cargar, modificar, etc.

Los eventos pueden ocurrir como resultado de una acción del usuario o del código del programa, también pueden ser originados por el sistema.

Propiedad:

Atributo de un objeto (nombre, color, fuente, posición, etc) que define una de las características del objeto, tal como su tamaño, color o localización en la pantalla, o un aspecto de su comportamiento, por ejemplo si está visible o activado.

Para cambiar las características de un objeto, se cambia el valor de sus propiedades.

Método:

Devolver objetos:

Macro:

Por lo tanto una macro consiste en una serie de comandos y funciones, que se almacenan en un módulo de Visual Basic y que puede ejecutarse siempre que sea necesario realizar la tarea.

Editor de Visual Basic:

Con el Editor de Visual Basic, se pueden modificar macros, copiar macros de un módulo en otro, copiar macros entre diferentes libros, cambiar de nombre a los módulos que almacenan macros o cambiar de nombre a las macros.

Objetos de Excel

Algunos de los objetos que se encuentran en Excel son: WorkSheet (Objeto hoja de cálculo) o Range (Objeto casilla o rango de casillas).

Un objeto Range está definido por una clase donde se definen sus propiedades. Entre las propiedades de un objeto Range están: Value , que contiene el valor de la casilla , Column y Row que contienen respectivamente la fila y la columna de la casilla, Font que contiene la fuente de los caracteres que muestra la casilla.

Range , como objeto, también tiene métodos; Por ejemplo el método Activate , hace activa una celda determinada, Clear , borra el contenido de una celda o rango de celdas, Copy , copia el contenido de la celda o rango de celdas en el portapapeles.

Range, es un elemento del Conjunto WorkSheets; dentro de un libro de trabajo puede existir más de una hoja ( WorkSheet ), todas las hojas de un libro de trabajo forman un conjunto, el conjunto WorkSheets .

Cada elemento individual de un conjunto se referencia por un índice, de esta forma, la primera, segunda y tercera hoja de un libro de trabajo, se referenciarán por WorkSheets(1), WorkSheets(2) y WorkSheets(3).

En este trabajo, se utilizarán objetos ya definidos por la aplicación Excel como WorkSheets, Range u otros. Sí se definirán sus propiedades y métodos de aplicación.

Editor de Visual Basic.

El editor de Visual Basic es la aplicación que utilizaremos para construir las macros que interactuarán junto con los libros de trabajo.

A continuación, prepararemos un archivo en el que escribiremos las primeras instrucciones en Visual Basic.

Preparar un archivo nuevo de Excel.

Maximice la ventana para trabajar más cómodamente, e intente tener activa la ventana Explorador de proyectos y la ventana Propiedades ( Ver/ Explorador de proyectos y Ver/ Ventana propiedades ).

Insertar un nuevo módulo.

Un módulo, sirve para agrupar procedimientos y funciones; siendo que el procedimiento y la función, son entidades de programación compuestas por instrucciones de código que realizan una acción concreta.

Módulo estándar

Es un módulo que contiene solamente declaraciones y definiciones de procedimiento, tipo y datos. Las declaraciones y definiciones a nivel de módulo, de un módulo estándar, son Public de manera predeterminada.

En versiones anteriores de Visual Basic un módulo estándar se denomina módulo de código.

El código dentro de un módulo se organiza en procedimientos; y un procedimiento le comunica a la aplicación cómo ejecutar una tarea específica.

Utilice procedimientos para dividir tareas de código complejas, en unidades más manipulables.

Procedimiento

Insertar un procedimiento.

Recordemos que un procedimiento es un bloque de instrucciones de código, que sirven para llevar a cabo alguna tarea específica.

Un procedimiento empieza siempre con la instrucción Sub Nombre_Procedimiento; Y termina con la instrucción End Sub .

A continuación crearemos un procedimiento para sumar dos valores, que se encuentran en la hoja1 del libro 1 de nuestro archivo Excel.

El primer término de la operación se encuentra en la celda A1 el segundo el la celda A2 y la operación, se suma, se encuentra en A3.

Para indicarle que nos referimos al rango A3, encerramos entre paréntesis esta referencia.

De este objeto Range ("A3"), indicamos que queremos establecer una fórmula para la propiedad Formula, observe que para separar el objeto de su propiedad utilizamos la notación punto "." .

Application

Application es el objeto superior, que en nuestro caso representa la aplicación Excel.

Así, el primer ejemplo, siguiendo toda la jerarquía de objetos quedaría de la forma siguiente:

Sub suma()
Application.Workbooks(1).Worksheets(1).Range("A3").Formula = "=A1+A2"
End Sub

Application, no siempre es necesario especificarlo; será necesario implementarlo, si en las macros se trabaja con diferentes libros de trabajo (diferentes archivos).

Ejecutar un procedimiento o función.

También puede hacer clic sobre el botón correspondiente en la barra de asistente o pulsar la tecla "F5" .

Para ejecutar el procedimiento desde la hoja de cálculo, debe estar en una hoja del Libro de Excel.

Se despliega una ventana que muestra una lista donde estás todas las macros incluidas en el libro de trabajo.

Formas

En este segundo ejemplo se ampliará la funcionalidad de la macro del ejemplo anterior.

Para asignar la Negrita y color, se aplica la propiedad Bold y Color del objeto Font .

Public Sub forma()
Range("A3").Formula = "=A1 + A2"
Selection.NumberFormat = "#,## 0$"
Range("A3").Font.Bold = True
Range("A3").Font.Color = RGB(0, 0, 255)
End Sub

El valor True , indica que la propiedad Bold está activada; para desactivarla, basta con igualarla al valor False .

Para establecer el color de la propiedad se utiliza la función RGB (Red , Green , Blue ), los tres argumentos para esta función son valores de que van de 0 a 255 y que corresponden a la intensidad de los respectivos colores Rojo, Verde y Azul.

Referenciar un rango de celdas.

Public Sub forma()
Range("A3").Formula = "=A1 + A2"
Selection.NumberFormat = "#,## 0$"
Range("A1:A3").Font.Bold = True
Range("A1:A3").Font.Color = RGB(0, 0, 255)
End Sub

Variables.

A continuación se realizará un programa que solicita al usuario, por medio de una ventana, ingresar un valor desde el teclado y el programa guarda a ese valor en una celda.

El programa utilizará una variable para poder registrar el valor (que el usuario ingresa por teclado), en la celda respectiva.

Siendo que una variable es simplemente una parte de memoria que, la función o procedimiento, se reserva para guardar datos.

Siendo variable el nombre que se asigna a la misma y Tipo el tipo de datos que se guardarán (números, texto, fecha, booleanos,...).

En el ejemplo, se declarará la variable de tipo String (tipo texto), y se realizará de la siguiente forma:

Así se está indicando que se reserve parte de la memoria que se llama Texto y que el tipo de datos que se guardarán ahí serán caracteres.

La Función InputBox .

Esta función muestra una ventana para que el usuario pueda teclear datos. Cuando se pulsa sobre el botón Aceptar , los datos entrados pasan a la variable a la que se ha igualado la función.

En este caso, si en la ventana que muestra InputBox pulsa sobre el botón Aceptar, los datos tecleados se guardarán el la variable Texto.

Sintaxis de InputBox: InputBox ( Mensaje , Título , Valor por defecto , Posición horizontal , Posición Vertical , Archivo ayuda , Número de contexto para la ayuda ).

Sub precio_impuesto()
Dim precio As Single
'Chr(13) sirve para que el mensaje se muestre en dos líneas
precio = InputBox("Introduzca precio sin impuesto" & Chr(13) & "El resultado se guardará en la casilla A1", "Entrada de datos")
ActiveSheet.Range("A1").Value = (precio * (1 + (0.21)))
End Sub

En este ejemplo, mediante un segundo Inputbox , el usuario decide en que celda se entran los datos del primer Inputbox.

Serán necesarias dos variables, una para guardar la celda destino escogida por el usuario y otra para guardar el valor.

Option Explicit
Sub precio_impuesto()
Dim celda As String
Dim precio As Single
celda = InputBox("En que celda quiere registrar el valor" & Chr(13) & "indicar letra de columna y número de fila", "Entrar Celda")
precio = InputBox("Ingrece el precio sin impuesto" & Chr(13) & "El resultado se guardará en la celda " & celda, "Entrada de datos")
ActiveSheet.Range(celda).Value = (precio * (1 + (0.21)))
End Sub

La sentencia Option Explicit.

En Visual Basic no es necesario declarar las variables, por ejemplo, en el programa anterior se hubiera podido prescindir de las líneas:

A pesar de ello, es recomendable que siempre se declaren las variables a utilizar; de esta forma se sabrá cuales son las variables que utiliza el procedimiento y que tipo de datos guarda cada una.

A medida que se vayan creando procedimientos más complicados y que requieran el uso de más variables, si no declara las variables al principio del procedimiento ocurrirán dos cosas:

Volviendo a la cuestión central, la sentencia Option Explicit al principio del módulo fuerza a que se declaren todas las variables.

Si al ejecutar el programa, se encuentra alguna variable sin declarar se producirá un error y no se podrá ejecutar el programa hasta que se declare.

El siguiente ejemplo muestra dos procedimientos con el mismo objetivo, en el primero no son declaradas las variables; y en el segundo sí se procede a la declaración de las variables.

Preste atención a las palabras "Texto" y "Testo", que simularán un error al teclear.

Sub Entrar_Valor()
Texto = InputBox("Introducir un texto " & Chr(13) & "Para la celda A1", "Entrada de datos")
ActiveSheet.Range("A1").Value = Testo
End Sub

Observe que el programa no hace lo que se pretende, pues Texto y Testo son dos variables diferentes y como no se ha declarado ninguna variable, ni se ha utilizado Option Explicit Visual Basic no da ningún tipo de error. Está ejecutando el programa pero no ingresa ningún valor.

Option Explicit
Sub Entrar_Valor()
Dim Texto As String
Texto = InputBox("Introducir un texto " & Chr(13) & "Para la celda A1", "Entrada de datos")
ActiveSheet.Range("A1").Value = Testo
End Sub

Observe que el programa no se ejecuta, al poner Option Explicit , forzamos a que se declaren todas las variables.

Visual Basic detecta que la variable Testo no ha sido declarada y así lo indica mostrando Error.

Entonces se puede detectar la existencia de un error y proceder a su modificación.

Tipos de datos en Visual Basic para Excel .

Byte	1 byte	0 a 255
Boolean	2 bytes	True o False
Integer	2 bytes	-32.768 a 32.767
Long(entero largo)	4 bytes	-2.147.483.648 a 2.147.483.647
Single (coma flotante/precisiónsimple)	4 bytes	-3,402823E38 a -1,401298E-45 para valores negativos; 1,401298E-45 a 3,402823E38 para valores positivos
Double (coma flotante/precisión doble)	8 bytes	-1,79769313486232E308 a -4,94065645841247E-324 para valores negativos; 4,94065645841247E-324 a 1,79769313486232E308 para valores positivos
Currency (entero a escala)	8 bytes	-922.337.203.685.477,5808 a 922.337.203.685.477,5807
Decimal	14 bytes	+/-79.228.162.514.264.337.593.543.950.335 sin punto decimal; +/-7,9228162514264337593543950335 con 28 posiciones a la derecha del signo decimal; el número más pequeño distinto de cero es+/- 0,0000000000000000000000000001
Date	8 bytes	1 de enero de 100 a 31 de diciembre de 9999
Object	4 bytes	Cualquier referencia a tipo Object
String(longitud variable)	10 bytes+ longitud de la cadena	Desde 0 a 2.000 millones
String(longitud fija)	Longitud de la cadena	Desde 1 a 65.400 aproximadamente
Variant(con números)	16 bytes	Cualquier valor numérico hasta el intervalo de un tipo Double
Variant (con caracteres)	22 bytes + longitud de cadena	El mismo intervalo que para un tipo String de longitud variable
Definido por el usuario(utilizando Type)	Número requerido por los elementos	El intervalo de cada elemento es el mismo que el intervalo de su tipo de datos.

Option Explicit
Sub tipo_dato()
Dim c As Integer
Dim t As Integer
Dim i As Integer
c = InputBox("Entrar el Capital Inicial", "Entrada de datos")
t = InputBox("Entrar el Tiempo", "Entrada de datos")
i = InputBox("Entrar el Interés", "Entrada de datos")
ActiveSheet.Range("A1").Value = (c * (1 + i) * t)
End Sub

Vuelva a ejecutar el programa y cuando se le pide el primer valor teclee "Hola". Observe que el programa se detiene indicando un error en el tipo de datos.

En el primer ejemplo no ha habido ningún problema, al entrar caracteres numéricos , estos pueden asignarse a variables tipo Integer porque Visual Basic hace automáticamente la conversión; pero al entrar texto e intentarlo asignar a una variable Integer Visual Basic muestra un error, indicando que la variable no es adecuada para los datos que se desean guardar.

Para solucionar estos problemas, se deben utilizar funciones de conversión de tipo.

Estas funciones, como su nombre lo indica, convierten datos de un tipo a otro, de String a Integer, de Integer a String, de Date a String,...

Sub convertir()
Dim c As Integer
Dim t As Integer
Dim i As Integer
c = val(InputBox("Entrar el Capital Inicia", "Entrada de datos"))
t = val(InputBox("Entrar el Tiempo", "Entrada de datos"))
i = val(InputBox("Entrar el Interés", "Entrada de datos"))
ActiveSheet.Range("A1").Value = (c * (1 + i) * t)
End Sub

La función Val(Dato String), devuelve los números contenidos en una cadena como un valor numérico del tipo adecuado.

Así, si al pedir un valor se teclea "Hola", la función Val devolverá un cero.

Conversión de Tipos de datos.

En el siguiente ejemplo se piden dos números, se suman y se guardan en la celda A1 de la hoja activa.

Option Explicit
Sub Sumar()
Dim Numero1 As Integer
Dim Numero2 As Integer
Numero1 = InputBox("Entrar el primer valor", "Entrada de datos")
Numero2 = InputBox("Entrar el primer valor", "Entrada de datos")
ActiveSheet.Range("A1").Value = Numero1 + Numero2
End Sub

Al ejecutar el procedimiento ingrese, en cada ventana, los valores 25 y 25 respectivamente.

Ahora, vuelva a ejecutar el programa y cuando se pide el primer valor teclee "Hola".

Con este nuevo evento el programa se detiene e indica un error en el tipo de datos.

En el primer caso del presente ejemplo, no se presentaron problemas al entrar caracteres numéricos. Éstos pueden asignarse a variables tipo Integer, porque Visual Basic hace automáticamente la conversión.

Pero al entrar texto e intentar asignarlo a una variable Integer, Visual Basic muestra un error indicando que la variable no es adecuada para los datos que se desean guardar.

Para solucionar este tipo de problemas se deben utilizar funciones de conversión de tipo.

Estas funciones, como su nombre indica, convierten datos de un tipo a otro, de String a Integer , de Integer a String , de Date a String ,...

Option Explicit
Sub Sumar()
Dim Numero1 As Integer
Dim Numero2 As Integer
Numero1 = Val(InputBox("Entrar el primer valor", "Entrada de datos"))
Numero2 = Val(InputBox("Entrar el primer valor", "Entrada de datos"))
ActiveSheet.Range("A1").Value = Numero1 + Numero2
End Sub

La función Val (Dato String), convierte una cadena de caracteres a valor numérico.

Así, si al pedir un valor se teclea "Hola", la función Val, devolverá un cero.

Funciones de conversión de tipos.

(Tabla copiada del ayudante de Office en línea de Referencia de Visual Basic para Excel).

1 Tenga en cuenta que para los ordenadores no es lo mismo el número 1 que el carácter "1".

En los lenguajes de programación actuales la conversión de carácter "1" a número 1 se hace automáticamente en muchos casos, esto es bueno y es malo.

Es bueno porque nos ahorra tener que hacer las conversiones y es malo porque es más difícil controlar ciertos casos.

Sólo para su información, el ordenador guarda el número 1 de la siguiente manera 00000001,mientras que el carácter "1" se guarda como 00110000 (el número 48 del código ASCII).

Función	Tipo devuelto	Intervalo del argumento expresión
Cbool	Boolean	Cualquier expresión de cadena o numérica válida.
Cbyte	Byte	0 a 255.
Ccur	Currency	-922.337.203.685.477,5808 a 922.337.203.685.477,5807.
Cdate	Date	Cualquier expresión de fecha.
CDbl	Double	-4,94065645841247E-324 para valores negativos; 4,94065645841247E-324 a 1,79769313486232E308 para valores positivos.
Cdec	Decimal	+/-7,9228162514264337593543950335. La menor posición para un número que no sea cero es 0,0000000000000000000000000001.
CInt	Integer	-32.768 a 32.767; las fracciones se redondean.
CLng	Long	-2.147.483.648 a 2.147.483.647; las fracciones se redondean.
CSng	Single	-3,402823E38 a -1,401298E-45 para valores negativos; 1,401298E-45 a 3,402823E38 para valores positivos.
CVar	Variant	El mismo intervalo que Double para valores numéricos. El mismo intervalo que String para valores no numéricos
CStr	String	El valor de retorno de CStr depende del argumento expresión.

Objetos y Propiedades de uso frecuente.

Objeto Cells(fila, columna).

Sirve, como el objeto range, para referenciar una celda o rango de celdas, pero en lugar de utilizar la referencia de la forma A1, B1, X320,... utiliza la fila y la columna que ocupa la celda dentro de la hoja (objeto WorkSheet).

Utilizar Cells para referenciar un rango.

La forma que se obtiene utilizando Cells es un poco más larga, pero se verá que a veces resulta mucho más funcional que utilizando únicamente range.

Pondrá en la celda A6 el valor "Hola", observe que en este ejemplo Cells comienza a contar filas y columnas a partir del rango especificado en el objeto Range.

Variables de Objetos.

Una variable objeto sirve para hacer referencia a un objeto, esto significa que podremos acceder a las propiedades de un objeto e invocar a sus métodos a través de la variable en lugar de hacerlo directamente a través del objeto.

Esta clase de variables se utilizan en estructuras For Each ... Next , o cuando es necesario construir funciones que devuelvan rangos o referencias a hojas.

Primero se asigna una variable objeto al objeto y luego se trabaja con esa variable de la misma forma que trabajaría directamente sobre el objeto.

Sub obj()
Dim R As Range
Set R = ActiveSheet.Range("A1:B10")
R.Value = "Hola"
R.Font.Bold = True
End Sub

El valor Nothing.

Cuando sea necesario desasignar una variable del objeto al cual hace referencia, deberá igualar la variable al valor Nothing de la siguiente forma :

Habitualmente se utiliza Nothing en una estructura condicional para comprobar si la variable objeto está asignada.

Observe que si se utiliza una variable objeto a la cual todavía no se le ha hecho ninguna asignación, el programa dará error y detendrá su ejecución.

Es de buena práctica hacer este tipo de comprobaciones antes de trabajar con variables objeto.

Estructuras condicionales.

Las estructuras condicionales son instrucciones de programación que permiten controlar la ejecución de un fragmento de código, en función de si se cumple o no una condición.

Instrucción if Condición then .. End if ( Si Condición Entonces ... Fin Si )

La estructura condicional que se construye con la instrucción Si Condición Entonces ... Fin Si tiene la forma siguiente:

Cuando el programa llega a la instrucción Si Condición Entonces , se evalúa la condición, si esta se cumple (es verdadera), se ejecutan todas las sentencias que están encerradas en el bloque, si no se cumple la condición (es falsa), se saltan estas sentencias.

Entrar un valor por el teclado con la instrucción InputBox y guardarlo en la celda A1 de la hoja activa.

Si el valor entrado desde el teclado (y guardado en A1) es superior a 1000, aplicar un descuento con otro InputBox y guardarlo en la celda A2 de la hoja activa.

Sub Condicional()
ActiveSheet.Range("A1").Value = 0
' Poner las casillas donde se guardan los valores 0 .
ActiveSheet.Range("A2").Value = 0
ActiveSheet.Range("A3").Value = 0
ActiveSheet.Range("A1").Value = Val(InputBox("Entrar el valor", "Entrar"))
' Si el valor de la celda A1 es mayor que 1000, entonces, aplicar descuento
If ActiveSheet.Range("A1").Value > 1000 Then
ActiveSheet.Range("A2").Value = Val(InputBox("Entrar Descuento", "Entrar"))
End If
ActiveSheet.Range("A3").Value = ActiveSheet.Range("A1").Value - ActiveSheet.Range("A2").Value
End Sub

Option Explicit
Sub Condicional()
Dim valor As String
Dim descuento As String
valor = 0
descuento = 0
valor = Val(InputBox("Entrar el valor", "Entrar"))
' Si el valor de la variable es mayor que 1000, entonces, pedir descuento
If valor > 1000 Then
descuento = Val(InputBox("Entrar Descuento", "Entrar"))
End If
ActiveSheet.Range("A1").Value = valor
ActiveSheet.Range("A2").Value = descuento
ActiveSheet.Range("A3").Value = valor - descuento
End Sub

Esta última alternativa es mas recomendable que la anterior pues las variables, aunque muchas veces "innecesarias", dejan a los programas más legibles y claros.

Esta buena práctica quedará evidenciada al momento de tener que realizar mantenimientos o modificaciones en el o los programas.

Sub Condicional2()
If ActiveSheet.Range("A1").Value = ActiveSheet.Range("A2").Value Then
ActiveSheet.Range("A1").Font.Color = RGB(0, 0, 255)
ActiveSheet.Range("A2").Font.Color = RGB(0, 0, 255)
End If
End Sub

Estructura If..Else

Esta estructura se utiliza cuando se requiere una respuesta alternativa a una condición.

Si se cumple la condición , se ejecuta el bloque de sentencias delimitado por Si Condición Entonces y Si no se cumple la condición, se ejecuta el bloque delimitado por Sino y Fin Si .

En Visual Basic la instrucción Si Condición Entonces ... Sino ... Fin Si se expresa con las instrucciones siguientes:

Entrar un valor por el teclado con la instrucción InputBox y guardarlo en la celda A1 de la hoja activa.

Si el valor entrado desde el teclado (y guardado en A1) es superior a 1000, aplicar un descuento del 10% sino aplicar un descuento del 5%, el descuento se guarda en la celda A2 de la hoja activa.

Sub Condicional_Else()
Dim valor As Single
Dim descuento As Single
valor = 0
valor = Val(InputBox("Entrar el valor", "Entrar"))
' Si el valor de la variable es mayor que 1000, entonces, aplicar descuento del 10%
If valor > 1000 Then
descuento = valor * (10 / 100)
ActiveSheet.Range("A2").Value = 0.1
Else
' Sino Aplicar descuento del 5%
descuento = valor * (5 / 100)
ActiveSheet.Range("A2").Value = 0.05
End If
ActiveSheet.Range("A1").Value = valor
ActiveSheet.Range("A3").Value = descuento
ActiveSheet.Range("A4").Value = valor - descuento
End Sub

Sub Condicional_Else2()
Range("A3").Value = Range("A1").Value - Range("A2").Value
If Range("A3").Value < 0 Then
Range("A3").Font.Color = RGB(255, 0, 0)
Else: Range("A3").Font.Color = RGB(0, 0, 255)
End If
End Sub

Estructuras If anidadas.

Sub Condicional()
If Range("A1").Value = Range("A2").Value Then
Range("A3").Value = "Los Valores de A1 y A2 son iguales"
Else
If Range("A1").Value > Range("A2").Value Then
Range("A3").Value = "A1 mayor que A2"
Else
Range("A3").Value = "A2 mayor que A1"
End If
End If
End Sub

Esta es una regla general, cuando pone un End If , este cierra siempre el último If ( o Else ) abierto.

Operadores lógicos.

Estos operadores lógicos, se utilizan cuando es preciso evaluar dos o más condiciones para decidir si se ejecutan o no determinadas acciones.

Operador Lógico And (Y).

Este operador se utiliza cuando: para ejecutar un bloque de instrucciones se cumpla más de una condición. Para que el bloque de instrucciones pueda ejecutarse se deberán cumplir todas las condiciones.

Sub Ejemplo_16()
Dim Producto As String
Dim Cantidad As Integer
Dim Precio As Single
Dim Total As Single
Dim Descuento As Single
Dim Total_Descuento As Single
Precio = 0
Producto = InputBox("Entrar Nombre del Producto", "Entrar")
Precio = Val(InputBox("Entrar el precio", "Entrar"))
Cantidad = Val(InputBox("Entrar la cantidad", "Entrar"))
Total = Precio * Cantidad
ActiveSheet.Range("A1").Value = Producto
ActiveSheet.Range("A2").Value = Precio
ActiveSheet.Range("A3").Value = Cantidad
ActiveSheet.Range("A4").Value = Total
' Si total mayor que 10.000 y el producto es Papa, aplicar descuento.
If Total > 10000 And Producto = "Papa" Then
Descuento = Val(InputBox("Entrar Descuento", "Entrar"))
Total_Descuento = Total * (Descuento / 100)
Total = Total - Total_Descuento
ActiveSheet.Range("A5").Value = Total_Descuento
ActiveSheet.Range("A6").Value = Total
End If
End Sub

Para que se ejecute el bloque de instrucciones entre If ... End If, deben cumplirse las dos condiciones que se evalúan; basta que no se cumpla una de ellas para que no se ejecute dicho bloque.

Operador Lógico Or (O).

Con este operador, para ejecutar un bloque de instrucciones es preciso que se cumpla, con por lo menos, alguna de una serie de condiciones.

Sub Ejemplo_17()
Dim Producto As String
Dim Cantidad As Integer
Dim Precio As Single
Dim Total As Single
Dim Descuento As Single
Dim Total_Descuento As Single
Precio = 0
Producto = InputBox("Entrar Nombre del Producto", "Entrar")
Precio = Val(InputBox("Entrar el precio", "Entrar"))
Cantidad = Val(InputBox("Entrar la cantidad", "Entrar"))
Total = Precio * Cantidad
ActiveSheet.Range("A1").Value = Producto
ActiveSheet.Range("A2").Value = Precio
ActiveSheet.Range("A3").Value = Cantidad
ActiveSheet.Range("A4").Value = Total
'Si total mayor que 10.000 o el producto es Papa, aplicar descuento
If Total > 10000 Or Producto = "Papa" Then
Descuento = Val(InputBox("Entrar Descuento", "Entrar"))
Total_Descuento = Total * (Descuento)
Total = Total - Total_Descuento
ActiveSheet.Range("A5").Value = Total_Descuento
ActiveSheet.Range("A6").Value = Total
End If
End Sub

Observe que para que se ejecute el bloque de instrucciones entre If ... End If, sólo es necesario que se cumpla alguna de las dos condiciones que se evalúan (o las dos a la vez); sólo cuando no se cumple ninguna de las dos no se ejecutan las instrucciones del bloque.

Operador Lógico Not (no).

Sub Ejemplo_18()
Dim Valor As Single
Dim Descuento As Single
Valor = 0
Descuento = 0
Valor = Val(InputBox("Entrar el Valor", "Entrar"))
' Si el valor de la variable NO es menor igual 1000, entonces, aplicar descuento
If Not (Valor <= 1000) Then
Descuento = Val(InputBox("Entrar Descuento", "Entrar"))
End If
ActiveSheet.Range("A1").Value = Valor
ActiveSheet.Range("A2").Value = Descuento
ActiveSheet.Range("A3").Value = Valor - Descuento
End Sub

Estructura Select Case.

Ejecuta uno de varios grupos de instrucciones, dependiendo del valor de una expresión.

Sub Ejemplo_19()
Dim Signo As String
Dim Valor1 As Integer
Dim Valor2 As Integer
Dim Total As Integer
Valor1 = ActiveSheet.Range("A1").Value
Valor2 = ActiveSheet.Range("A2").Value
Signo = ActiveSheet.Range("B1").Value
Total = 0
If Signo = "+" Then
Total = Valor1 + Valor2
End If
If Signo = "-" Then
Total = Valor1 - Valor2
End If
If Signo = "x" Then
Total = Valor1 * Valor2
End If
If Signo = ":" Then
Total = Valor1 / Valor2
End If
ActiveCell.Range("A3").Value = Total
End Sub

Con el objetivo de lograr una mejor legibilidad, se debe utilizar la instrucción Select Case.

Sub Ejemplo_20()
Dim Signo As String
Dim Valor1 As Integer
Dim Valor2 As Integer
Dim Total As Integer
Valor1 = ActiveSheet.Range("A1").Value
Valor2 = ActiveSheet.Range("A2").Value
Signo = ActiveSheet.Range("B1").Value
Select Case Signo
Case "+"
Total = Valor1 + Valor2
Case "-"
Total = Valor1 - Valor2
Case "x"
Total = Valor1 * Valor2
Case ":"
Total = Valor1 / Valor2
Case Else
Total = 0
End Select
ActiveCell.Range("A3").Value = Total
End Sub

Sub Ejemplo_21()
Dim Nota1 As Integer
Dim Nota2 As Integer
Dim Nota3 As Integer
Dim Media As Single
Nota1 = Val(InputBox("Entrar Nota primera evaluación", "Nota"))
Nota2 = Val(InputBox("Entrar Nota Segunda evaluación", "Nota"))
Nota3 = Val(InputBox("Entrar Nota Tercera evaluación", "Nota"))
Media = (Nota1 + Nota2 + Nota3) / 3
ActiveSheet.Range("A1").Value = Nota1
ActiveSheet.Range("A2").Value = Nota2
ActiveSheet.Range("A3").Value = Nota3
ActiveSheet.Range("A4").Value = Media
Select Case Media
Case 0 To 2
ActiveSheet.Range("A5").Value = "Muy deficiente"
Case 3
ActiveSheet.Range("A5").Value = "Deficiente"
Case 4
ActiveSheet.Range("A5").Value = "Insuficiente"
Case 5
ActiveSheet.Range("A5").Value = "Suficiente"
Case 6
ActiveSheet.Range("A5").Value = "Bien"
Case 7 To 8
ActiveSheet.Range("A5").Value = "Notable"
Case Is > 8
ActiveSheet.Range("A5").Value = "Sobresaliente"
End Select
End Sub

Funciones de comprobación.

Funciones que son útiles para comprobar o validar el tipo de datos entrados desde teclado, o los datos contenidos en una casilla.

Sub Ejemplo_22()
Dim Signo As String
Dim Valor1 As Integer
Dim Valor2 As Integer
Dim Total As Integer
Valor1 = ActiveSheet.Range("A1").Value
Valor2 = ActiveSheet.Range("A2").Value
Signo = ActiveSheet.Range("B1").Value
Select Case Signo
Case "+"
Total = Valor1 + Valor2
Case "-"
Total = Valor1 - Valor2
Case "x"
Total = Valor1 * Valor2
Case ":"
Total = Valor1 / Valor2
Case Else
Total = 0
End Select
ActiveCell.Range("A3").Value = Total
End Sub

Si en alguna de las casillas que se deben operar no hubiera ningún valor o bien datos alfanuméricos, al ejecutar la macro se producirá un error.

Aunque con Visual Basic se puede controlar el flujo del programa cuando se produce un error imprevisto, para solucionar este problema se utiliza una función de comprobación que indica si en las casillas A1 y A2 hay valores adecuados (en nuestro caso numéricos) para proseguir con la ejecución de la macro, en caso contrario se mostrará un error y no se ejecutará ninguna de las operaciones.

La función que utilizaremos es IsNumeric (expresión), esta función devuelve un valor True si la expresión que se evalúa es un valor numérico, en caso contrario devuelve False .

También se utiliza la función IsEmpty para comprobar si en B1 hay algo, IsEmpty (Expresión) evalúa si expresión está vacía, devuelve True si es así y False en caso contrario.

Sub Ejemplo_23()
Dim Signo As String
Dim Valor1 As String
Dim Valor2 As String
Dim Total As String
Dim Continuar As Boolean
Valor1 = ActiveSheet.Range("A1").Value
Valor2 = ActiveSheet.Range("A2").Value
Signo = ActiveSheet.Range("B1").Value
Continuar = True
' Si en la celda A1 no hay un valor numérico
If Not IsNumeric(ActiveSheet.Range("A1")) Then
MsgBox Prompt:="En la celda A1 no hay ningún valor numérico", Title:="ERROR"
Continuar = False
End If
' Si en la celda A2 no hay un valor numérico
If Not IsNumeric(ActiveSheet.Range("A2")) Then
MsgBox Prompt:="En la celda A2 no hay ningún valor numérico", Title:="ERROR"
Continuar = False
End If
If IsEmpty(ActiveSheet.Range("B1")) Then
MsgBox Prompt:="En la celda B1 no hay ningún operador (+,-,x,:)", Title:="ERROR"
End If
End Sub

En lugar de los tres If de comprobación se puede aplicar el operador OR, de la manera siguientes:

Sub Ejemplo_24()
Dim Signo As String
Dim Valor1 As String
Dim Valor2 As String
Dim Total As String
Dim Continuar As Boolean
Valor1 = ActiveSheet.Range("A1").Value
Valor2 = ActiveSheet.Range("A2").Value
Signo = ActiveSheet.Range("B1").Value
Continuar = True
' Si en la celda A1 no hay un valor numérico
If Not IsNumeric(ActiveSheet.Range("A1")) Or Not IsNumeric(ActiveSheet.Range("A2")) Or IsEmpty(ActiveSheet.Range("B1")) Then
MsgBox Prompt:="Debe entrar números en A1 y A2 y un signo (+,-,x, : ) en B1", Title:="ERROR"
Else
' Instrucciones de las operaciones .......
End If
End Sub

Lista de Funciones de Comprobación.

IsNuméric (Expresión): Comprueba si expresión tiene un valor que se puede interpretar como numérico.

IsDate (Expresión): Comprueba si expresión tiene un valor que se puede interpretar como tipo fecha.

IsEmpty (Expresión): Comprueba que expresión tenga algún valor, que se haya inicializado.

IsObject (Expresión): Comprueba si expresión (una variable) representa una variable tipo objeto.

IsNull (Expresión): Comprueba si expresión contiene un valor nulo debido a datos no válidos.

Nothing: No es propiamente una función, sirve para comprobar si una variable objeto esta asociada a un objeto antes de hacer cualquier operación con ella.

Para trabajar con una variable objeto antes debe asignarse a uno mediante la instrucción Set , en caso contrario se producirá un error en el programa cuando utilice el objeto y se detendrá su ejecución.

Sub Obj()
Dim R As Range
' Si la variable R es Nothing es que no ha sido asignada, no se puede trabajar con ella
If R Is Nothing Then
MsgBox Prompt:="La variable Objeto no ha sido asignada", Buttons:=vbOK, Title:="Error"
Else
R.Value = "Hola"
End If
End Sub

Para trabajar con una variable objeto debe asignarse a uno, mediante la instrucción Set

Sub Obj()
Dim R As Range
Set R = ActiveSheet.Range("A1")
' Si la variable R es Nothing es que no ha sido asignada, no se puede trabajar con ella
If R Is Nothing Then
MsgBox Prompt:="La variable Objeto no ha sido asignada", Buttons:=vbOK, Title:="Error"
Else
R.Value = "Hola"
End If
End Sub

La función MsgBox.

Esta función muestra un mensaje en un cuadro de diálogo hasta que el usuario pulse un botón.

La función devuelve un dato tipo Integer en función del botón pulsado por el usuario.

Sintáxis de MsgBox. MsgBox ( Mensaje, Botones, Título, Archivo de ayuda, contexto)

Mensaje: Obligatorio, es el mensaje que se muestra dentro del cuadro de diálogo.

Botones: Opcional. Es un número o una suma de números o constantes (vea tabla Valores para botones e Iconos), que sirve para mostrar determinados botones e iconos dentro del cuadro de diálogo.

Título: Opcional. Es el texto que se mostrará en la barra del título del cuadro de diálogo.

Archivo de Ayuda : Opcional. Si ha asignado un texto de ayuda al cuadro de diálogo, aquí debe especificar el nombre del archivo de ayuda donde está el texto.

Context: Opcional. Es el número que sirve para identificar el texto al tema de ayuda correspondiente que estará contenido en el archivo especificado en el parámetro

Tabla para botones e iconos del cuadro MsgBox . (Tabla copiada del archivo de ayuda de Microsoft Excel).

VbApplicationModal 0 Aplicación modal; el usuario debe responder al cuadro de mensajes antes de poder seguir trabajando en la aplicación actual.

VbSystemModal 4096 Sistema modal; se suspenden todas las aplicaciones hasta que el usuario responda al cuadro de mensajes.

El primer grupo de valores (0 a 5) describe el número y el tipo de los botones mostrados en el cuadro de diálogo; el segundo grupo (16, 32, 48, 64) describe el estilo del icono, el tercer grupo (0, 256, 512) determina el botón predeterminado y el cuarto grupo (0, 4096) determina la modalidad del cuadro de mensajes.

Cuando se suman números para obtener el valor final del argumento buttons, se utiliza solamente un número de cada grupo.

Nota: Estas constantes las especifica Visual Basic for Applications.Por lo tanto, el nombre de las mismas puede utilizarse en cualquier lugar del código en vez de sus valores reales.

Los valores que puede devolver la función msgbox en función del botón que pulse el usuario se muestran en la tabla siguiente.

Tabla de valores que puede devolver MsgBox. (Tabla copiada del archivo de ayuda de Microsoft Visual Basic para aplicaciones).

Constante Valor Descripción VbOK 1 Aceptar VbCancel 2 Anular VbAbort 3 Cancelar VbRetry 4 Reintentar VbIgnore 5 Ignorar VbYes 6 Sí VbNo 7 No

Sub Ejemplo_27()
Dim Producto As String
Dim Cantidad As Single
Dim Precio As Single
Dim Total As Single
Dim Descuento As Single
Dim Total_Descuento As Single
Precio = 0
Producto = InputBox("Entrar Nombre del Producto", "Entrar")
Precio = Val(InputBox("Entrar el precio", "Entrar"))
Cantidad = Val(InputBox("Entrar la cantidad", "Entrar"))
Total = Precio * Cantidad
With ActiveSheet
Range("A1").Value = Producto
Range("A2").Value = Precio
Range("A3").Value = Cantidad
Range("A4").Value = Total
End With
' Si total mayor que 10.000 o el producto es papa, aplicar descuento.
If Total > 10000 Or Producto = "papa" Then
Descuento = Val(InputBox("Entrar Descuento", "Entrar"))
Total_Descuento = Total * (Descuento / 100)
Total = Total - Total_Descuento
With ActiveSheet
Range("A5").Value = Total_Descuento
Range("A6").Value = Total
End With
End If
End Sub

Estructuras Repetitivas.

Este tipo de estructuras permiten ejecutar más de una vez el mismo bloque de sentencias.

Sub Ejemplo_28()
Dim Nota As Integer
Dim Media As Single
Media = 0
Nota = Val(InputBox("Entrar la 1 Nota : ", "Entrar Nota"))
ActiveSheet.Range("A1").Value = Nota
Media = Media + Nota
Nota = Val(InputBox("Entrar la 2 Nota : ", "Entrar Nota"))
ActiveSheet.Range("A2").Value = Nota
Media = Media + Nota
Nota = Val(InputBox("Entrar la 3 Nota : ", "Entrar Nota"))
ActiveSheet.Range("A3").Value = Nota
Media = Media + Nota
Nota = Val(InputBox("Entrar la 4 Nota : ", "Entrar Nota"))
ActiveSheet.Range("A4").Value = Nota
Media = Media + Nota
Nota = Val(InputBox("Entrar la 5 Nota : ", "Entrar Nota"))
ActiveSheet.Range("A5").Value = Nota
Media = Media + Nota
Media = Media / 5
ActiveSheet.Range("A6").Value = Media
End Sub

Para evitar esta tipo de repeticiones de código, los lenguajes de programación incorporan instrucciones que permiten la repetición de bloques de código.

Estructura repetitiva Para (for).

Esta estructura repite un grupo de instrucciones un número especificado de veces.

Var es una variable que la primera vez que se entra en el bucle se iguala a Valor_Inicial , las sentencias del bucle se ejecutan hasta que Var llega al Valor_Final , cada vez que se ejecutan el bloque de instrucciones Var se incrementa según el valor de Incremento .

En Visual Basic para Excel la estructura Para se implementa con la instrucción For ... Next .

Sub Ejemplo_29()
Dim i As Integer
Dim Total As Integer
Dim Valor As Integer
For i = 1 To 10
Valor = Val(InputBox("Entrar un valor", "Entrada"))
Total = Total + Valor
Next i
ActiveCell.Range("A1").Value = Total
End Sub

Recorrer casillas de una hoja de cálculo.

Una operación bastante habitual cuando se trabaja con Excel es el recorrido de rangos de casillas para llenarlas con valores, mirar su contenido, etc.

Las estructuras repetitivas son imprescindibles para recorrer grupos de celdas o rangos.

En los siguientes ejemplos se podrá observar la utilización de estructuras repetitivas para recorrer rangos de casillas, observe la utilización de las propiedades Cells y Offset .

Propiedad Cells.

Esta propiedad, sirve para referenciar una celda o un rango de celdas según coordenadas de fila y columna.

Sub Ejemplo_30()
Dim Fila As Integer
Dim i As Integer
Fila = 1
For i = 2 To 10 Step 2
ActiveSheet.Cells(Fila, 1).Value = i
Fila = Fila + 1
Next i
End Sub

Sub Ejemplo_31()
Dim Celda_Inicial As String
Dim i As Integer
Dim Fila As Integer
Dim Columna As Integer
Celda_Inicial = InputBox("Introducir la celda Inicial (Letra de columna y Número de Fila): ", "Celda Inicial")
ActiveSheet.Range(Celda_Inicial).Activate
' Tomar el valor de fila de la celda activa sobre la variable Fila
Fila = ActiveCell.Row
' Tomar el valor de columna de la celda activa sobre la variable Fila
Columna = ActiveCell.Column
For i = 1 To 10
ActiveSheet.Cells(Fila, Columna).Value = i
Fila = Fila + 1
Next i
End Sub

Propiedades ROW y COLUMN.

Como habrá deducido del ejemplo anterior devuelven la fila y la columna de un objeto range.

En el ejemplo anterior se utilizaban concretamente para obtener la fila y la columna de la celda activa.

Sub Ejemplo_32()
Dim Celda_Inicial As String
Dim i As Integer
Dim Fila As Integer
Dim Columna As Integer
Celda_Inicial = InputBox("Introducir la celda Inicial (Letra de la Columna y Número de la Fila): ", "Celda Inicial")
ActiveSheet.Range(Celda_Inicial).Activate
Fila = 1
For i = 1 To 10
ActiveSheet.Range(Celda_Inicial).Cells(Fila, 1).Value = i
Fila = Fila + 1
Next i
End Sub

** Recuerde que cuando utilizamos Cells como propiedad de un rango (Objeto Range), Cells empieza a contar a partir de la celda referenciada por Range .

Sub Ejemplo_33()
Dim Nota As Integer
Dim Media As Single
Dim Fila As Integer
Media = 0
For Fila = 1 To 5
Nota = Val(InputBox("Entrar la " & Fila & " Nota : ", "Entrar Nota"))
ActiveSheet.Cells(Fila, 1) = Nota
Media = Media + Nota
Next Fila
End Sub

Propiedad Offset.

Devuelve un objeto Range que representa un rango desplazado con respecto al rango especificado. Es de sólo lectura.

Sub Ejemplo_34()
Dim Nota As Integer
Dim Media As Single
Dim Fila As Integer
Media = 0
ActiveSheet.Range("A1").Activate
For Fila = 0 To 4
Nota = Val(InputBox("Entrar la " & Fila + 1 & " Nota : ", "Entrar Nota"))
ActiveCell.Offset(Fila, 0).Value = Nota
Media = Media + Nota
Next Fila
Media = Media / 5
ActiveCell.Offset(6, 1).Value = Media
End Sub

Sub Ejemplo_35()
Dim Nota As Integer
Dim Media As Single
Dim i As Integer
Media = 0
ActiveSheet.Range("A1").Activate
For i = 1 To 5
Nota = Val(InputBox("Entrar la " & i & " Nota : ", "Entrar Nota"))
ActiveCell.Value = Nota
Media = Media + Nota
'Hacer activa la celda situada una fila por debajo de la actual
ActiveCell.Offset(1, 0).Activate
Next
Media = Media / 5
ActiveCell.Value = Media
End Sub

Estructura repetitiva Do While..Loop (Hacer Mientras).

Do While ...Loop repite un bloque de instrucciones cuando una condición es verdadera, o hasta que una condición se convierta en falsa.

Para las situaciones en que se sabe previamente el número de veces que se ha de repetir un proceso, la estructura repetitiva for resulta conveniente.

Pero cuando previamente no se sabe el número de veces que se debe repetir un proceso, deberemos recurrir a la sentencia Do While ... Loop en alguna de sus formas.

Esta estructura repetitiva, Do While .. Loop, está controlada por una o varias condiciones; la repetición del bloque de sentencias dependerá, de si se va cumpliendo la condición o las condiciones.

El programa va pidiendo datos mientras se entre un valor en el InputBox correspondiente al Nombre.

Cuando al preguntar el Nombre no se entre ningún valor, terminará la ejecución del bloque encerrado entre Do While ... Loop.

Sub Ejemplo_36()
Dim Nombre As String
Dim Ciudad As String
Dim Edad As Integer
Dim fecha As Date
' Activar hoja1
Worksheets("Hoja1").Activate
'Activar celda A2
ActiveSheet.Range("A2").Activate
Nombre = InputBox("Entre el Nombre (Return para Terminar) : ", "Nombre")
' Mientras la variable Nombre sea diferente a cadena vacía
Do While Nombre <> ""
Ciudad = InputBox("Entre la Ciudad : ", "Ciudad")
Edad = Val(InputBox("Entre la Edad : ", "Edad"))
fecha = CDate(InputBox("Entra la Fecha (dd-mm-aa) : ", "Fecha"))
' Copiar los datos en las casillas correspondientes
With ActiveCell
.Value = Nombre
.Offset(0, 1).Value = Ciudad
.Offset(0, 2).Value = Edad
.Offset(0, 3).Value = fecha
End With
'Hacer activa la celda de la fila siguiente a la actual
ActiveCell.Offset(1, 0).Activate
Nombre = InputBox("Entre el Nombre (Return para Terminar) : ", "Nombre")
Loop
End Sub

En este ejemplo, siempre se empieza a llenar el rango a partir de la celda A2, consecuentemente, la segunda vez que ejecute la macro destruirá los datos registrados anteriormente.

La estructura del ejemplo 37 recorrerá una fila de celdas a partir de A1 hasta encontrar una vacía y dejará a esta como celda activa para que la entrada de datos comience a partir de ella.

Sub Ejemplo_37()
'Activar hoja1
Worksheets("Hoja1").Activate
'Activar celda A2
ActiveSheet.Range("A1").Activate
' Mientras la celda activa no esté vacía
Do While Not IsEmpty(ActiveCell)
' Hacer activa la celda situada una fila por debajo de la actual
ActiveCell.Offset(1, 0).Activate
Loop
End Sub

Sub Ejemplo_38()
Dim Nombre As String
Dim Ciudad As String
Dim Edad As Integer
Dim fecha As Date
Worksheets("Hoja1").Activate
ActiveSheet.Range("A1").Activate
' Buscar la primera celda vacía de la columna A y convertirla en activa
Do While Not IsEmpty(ActiveCell)
ActiveCell.Offset(1, 0).Activate
Loop
Nombre = InputBox("Entre el Nombre (Return para Terminar) : ", "Nombre")
' Mientras la variable Nombre sea diferente a cadena vacía
Do While Nombre <> ""
Ciudad = InputBox("Entre la Ciudad : ", "Ciudad")
Edad = Val(InputBox("Entre la Edad : ", "Edad"))
fecha = CDate(InputBox("Entra la Fecha (dd-mm-aa) : ", "Fecha"))
With ActiveCell
.Value = Nombre
.Offset(0, 1).Value = Ciudad
.Offset(0, 2).Value = Edad
.Offset(0, 3).Value = fecha
End With
ActiveCell.Offset(1, 0).Activate
Nombre = InputBox("Entre el Nombre (Return para Terminar) : ", "Nombre")
Loop
End Sub

Sub Ejemplo_39()
Dim Nombre As String
Dim Ciudad As String
Dim Edad As Integer
Dim fecha As Date
Dim Mas_datos As Integer

Worksheets("Hoja1").Activate
ActiveSheet.Range("A1").Activate
' Buscar la primera celda vacía de la columna A y convertirla en activa
Do While Not IsEmpty(ActiveCell)
ActiveCell.Offset(1, 0).Activate
Loop
Mas_datos = vbYes
Do While Mas_datos = vbYes
Nombre = InputBox("Entre el Nombre (Return para Terminar) : ", "Nombre")
Ciudad = InputBox("Entre la Ciudad : ", "Ciudad")
Edad = Val(InputBox("Entre la Edad : ", "Edad"))
fecha = CDate(InputBox("Entra la Fecha (dd-mm-aa): ", "Fecha"))
With ActiveCell
.Value = Nombre
.Offset(0, 1).Value = Ciudad
.Offset(0, 2).Value = Edad
.Offset(0, 3).Value = fecha
End With
ActiveCell.Offset(1, 0).Activate
' Preguntar al usuario si desea entrar otro registro.
Mas_datos = MsgBox("Otro registro ?", vbYesNo + vbQuestion, "Entrada de datos")
Loop
End Sub

Es preciso incorporar la variable Mas_datos, que es una variable, de tipo Integer .

Estructura Do...Loop While.

Esta estructura, repite un bloque de instrucciones cuando una condición es verdadera, o hasta que una condición se convierta en falsa; la condición se evalúa al final; consecuentemente las instrucciones del cuerpo del bucle se ejecutaran al menos una vez .

Sub Ejemplo_40()

Dim Nombre As String
Dim Ciudad As String
Dim Edad As Integer
Dim fecha As Date
Dim Mas_datos As Integer

Worksheets("Hoja1").Activate
ActiveSheet.Range("A1").Activate
' Buscar la primera celda vacía de la columna A y convertirla en activa
Do While Not IsEmpty(ActiveCell)
ActiveCell.Offset(1, 0).Activate
Loop
Do
Nombre = InputBox("Entre el Nombre (Return para Terminar) : ", "Nombre")
Ciudad = InputBox("Entre la Ciudad : ", "Ciudad")
Edad = Val(InputBox("Entre la Edad : ", "Edad"))
fecha = CDate(InputBox("Entra la Fecha : ", "Fecha"))

With ActiveCell
.Value = Nombre
.Offset(0, 1).Value = Ciudad
.Offset(0, 2).Value = Edad
.Offset(0, 3).Value = fecha
End With
ActiveCell.Offset(1, 0).Activate
Mas_datos = MsgBox("Otro registro ?", vbYesNo + vbQuestion, "Entrada de datos")
'Mientras Mas_Datos = vbYes
Loop While Mas_datos = vbYes
End Sub

No es precisa la línea "Mas_Datos = vbYes" antes de Do para forzar la entrada en el bucle, pues la condición va al final.

Estructura Do...Loop Until (Hacer.. Hasta que se cumpla la condición).

Repite instrucciones hasta que una condición llegue a ser verdadera.
Hay dos formas de utilizar la palabra clave Until para comprobar el estado de una condición en una instrucción Do...Loop:

Sub Ejemplo_41()

Dim Nombre As String
Dim Ciudad As String
Dim Edad As Integer
Dim fecha As Date
Dim Mas_datos As Integer

Worksheets("Hoja1").Activate
ActiveSheet.Range("A1").Activate
' Buscar la primera celda vacía de la columna A y convertirla en activa
Do While Not IsEmpty(ActiveCell)
ActiveCell.Offset(1, 0).Activate
Loop
Do
Nombre = InputBox("Entre el Nombre (Return para Terminar) : ", "Nombre")
Ciudad = InputBox("Entre la Ciudad : ", "Ciudad")
Edad = Val(InputBox("Entre la Edad : ", "Edad"))
fecha = CDate(InputBox("Entra la Fecha : ", "Fecha"))

With ActiveCell
.Value = Nombre
.Offset(0, 1).Value = Ciudad
.Offset(0, 2).Value = Edad
.Offset(0, 3).Value = fecha
End With
ActiveCell.Offset(1, 0).Activate
Mas_datos = MsgBox("Otro registro ?", vbYesNo + vbQuestion, "Entrada de datos")
'Hasta que Mas_Datos sea igual a vbNo
Loop Until Mas_datos = vbNo
End Sub

Estructura For Each.

Este bucle se utiliza básicamente para ejecutar un grupo de sentencias con los elementos de una colección o una matriz (pronto veremos los que es).

Vea el ejemplo siguiente que se utiliza para cambiar los nombres de las hojas de un libro de trabajo.

Programa que pregunta el nombre para cada hoja de un libro de trabajo, si no se pone nombre a la hoja, queda el que tiene.

Sub Ejemplo_42()
Dim Nuevo_Nombre As String
Dim Hoja As Worksheet
' Para cada hoja del conjunto Worksheets
For Each Hoja In Worksheets
Nuevo_Nombre = InputBox("Nombre de la Hoja : " & Hoja.Name, "Nombrar Hojas")
If Nueva_Nombre <> "" Then
Hoja.Name = Nuevo_Nombre
End If
Next
End Sub

** Hoja va referenciando cada una de las hojas del conjunto WorkSheets a cada paso de bucle.

Procedimientos y funciones.

Se define como procedimiento o función a un bloque de código que realiza alguna tarea. Hasta ahora, se han construido los programas utilizando un único procedimiento, pero a medida que los programas (y los problemas) crecen se va haciendo necesaria la inclusión de más procedimientos.

Podría fácilmente caer en la tentación de utilizar, como hasta ahora, un único procedimiento por programa pero se dará cuenta rápidamente de que este método no es nada práctico ya que grandes bloques de código implican mayor complicación del mismo, repetición de sentencias y lo que es más grave, mayores problemas de seguimiento a la hora de depurar errores, ampliar funcionalidades o incluir modificaciones.

La filosofía de utilizar procedimientos es la antigua fórmula del "divide y vencerás", es decir, con los procedimientos podremos tratar cada problema o tarea de forma más o menos aislada de forma que construiremos el programa paso a paso evitando tener que resolver o controlar múltiples cosas a la vez.

Cada tarea la realizará un procedimiento, si esta tarea implica la ejecución de otras tareas, cada una se implementará y solucionará en su correspondiente procedimiento de manera que cada uno haga una cosa concreta. Así, los diferentes pasos que se deben ejecutar para que un programa haga algo, quedaran bien definidos cada uno en su correspondiente procedimiento, si el programa falla, fallará a partir de un procedimiento y de esta forma podremos localizar el error más rápidamente.

Los procedimientos son también un eficaz mecanismo para evitar la repetición de código en un mismo programa e incluso en diferentes programas. Suponemos que habrá intuido que hay muchas tareas que se repiten en casi todos los programas, veremos como los procedimientos que ejecutan estas tareas se pueden incluir en un módulo de forma que este sea exportable a otros programas y de esta manera ganar tiempo que, como dice el tópico, es precioso.

Definir un procedimiento.

Llamar a un procedimiento.

Para llamar un procedimiento desde otro se utiliza la instrucción Call Nombre_Procedimiento.

Las secuencias del procedimiento P_Uno se ejecutan hasta llegar a la línea Call P_Dos, entonces se salta al procedimiento P_Dos, se ejecutan todas las sentencias de este procedimiento y el programa continua ejecutándose en el procedimiento P_Uno a partir de la sentencia que sigue a Call P_Dos.

En este ejemplo, el código que salta casilla hasta que se encuentra una vacía se implementa en un procedimiento llamado, Saltar_Celdas_Llenas. Observe que para entrar valores se ha sustituido Do While..Loop por Do.. Loop While.

Sub Ejemplo_43()
Dim Nombre As String
Dim Ciudad As String
Dim Edad As Integer
Dim fecha As Date

' Llamada a la función Saltar_Celdas_Llenas, el programa salta aquí a ejecutar las
'instrucciones de este procedimiento y luego vuelve para continuar la ejecución a partir de la
'instrucción Do
Call Saltar_Celdas_Llenas
Do
Nombre = InputBox("Entre el Nombre : ", "Nombre")
Ciudad = InputBox("Entre la Ciudad : ", "Ciudad")
Edad = Val(InputBox("Entre la Edad : ", "Edad"))
Fecha=Cdate(InputBox("Entra la Fecha : ", "Fecha"))
With ActiveCell
.Value = Nombre
.Offset(0,1).Value = Ciudad
.Offset(0,2).Value = Edad
.Offset(0,3).value = fecha
End With
ActiveCell.Offset(1,0).Activate
Mas_datos = MsgBox("Otro registro ?", vbYesNo+vbQuestion,"Entrada de datos")
Loop While Mas_Datos = vbYes
End Sub

' Función que salta celdas de una misma columna. Sirve para encontrar la primera celda vacía de la
' columna
Sub Saltar_Celdas_Llenas()
WorkSheets("Hoja1").Activate
ActiveSheet.Range("A1").Activate
Do While not IsEmpty(ActiveCell)
ActiveCell.Offset(1,0).Activate
Loop
End Sub

Generalizar una función.

Observe que para saltar un rango de casillas llenas sólo necesitará llamar a la función Saltar_Celdas_Llenas, pero, siempre y cuando este rango esté en una hoja llamada "Hoja1" y empiece en la casilla A1, el procedimiento es poco práctico ya que su ámbito de funcionamiento es limitado. En la siguiente sección modificaremos el procedimiento de manera que sirva para recorrer un rango que empiece en cualquier casilla de cualquier hoja.

Parámetros.

Los parámetros son el mecanismo por el cual un procedimiento puede pasarle valores a otro y de esta forma condicionar, moldear, etc. las acciones que ejecuta. El procedimiento llamado gana entonces en flexibilidad. La sintaxis de llamada de un procedimiento es la siguiente, Call Procedimiento (Parámetro1, Parámetro2,..., ParámetroN).

La sintaxis para el procedimiento llamado es la siguiente,
Sub Procedimiento(Parámetro1 as Tipo, Parámetro2 As Tipo,..., Parámetro3 As Tipo)

Observe que aquí los parámetros son variables que recibirán los valores, evidentemente debe haber coincidencia de tipo.
Por ejemplo, si el primer parámetro es una variable tipo Integer, el primer valor que se le debe pasar al procedimiento cuando se llama también ha de ser de tipo Integer (recuerde que puede ser un valor directamente o una variable).

Ahora la función Saltar_Celdas_Llenas tiene dos parámetros Hoja y Casilla_Inicial que reciben respectivamente la hoja donde está el rango a recorrer y la casilla inicial del rango.

Sub Ejemplo_44()
Dim Nombre As String
Dim Ciudad As String
Dim Edad As Integer
Dim fecha As Date
' Llamada a la función Saltar_Celdas_Llenas, observar que mediante dos parámetros se indica
' al procedimiento en que hoja está el rango a saltar y en la casilla donde debe empezar.
Call Saltar_Celdas_Llenas("Hoja1", "A1")
Do
Nombre = InputBox("Entre el Nombre (Return para Terminar) : ", "Nombre")
Ciudad = InputBox("Entre la Ciudad : ", "Ciudad")
Edad = Val(InputBox("Entre la Edad : ", "Edad"))
Fecha=Cdate(InputBox("Entre la Fecha : ", "Fecha"))
With ActiveCell
.Value = Nombre
.Offset(0,1).Value = Ciudad
.Offset(0,2).Value = Edad
.Offset(0,3).value = fecha
End With
ActiveCell.Offset(1,0).Activate
Mas_datos = MsgBox("Otro registro ?", vbYesNo+vbQuestion,"Entrada de datos")
Loop While Mas_Datos = vbYes
End Sub
'
' Procedimiento Saltar_Celdas_Llenas.
' Sirve para Saltar celdas llenas de una columna hasta encontrar una vacía que se convierte en activa
' Parámetros :
' Hoja : Hoja donde está el rango a saltar.
' Casilla_Inicial : Casilla Inicial de la columna
Sub Saltar_Celdas_Llenas(Hoja As String, Casilla_Inicial As String)
WorkSheets(Hoja).Activate
ActiveSheet.Range(Casilla_Inicial).Activate
Do While not IsEmpty(ActiveCell)
ActiveCell.Offset(1,0).Activate
Loop
End Sub

Observe que ahora el procedimiento Saltar_Celdas_Llenas sirve para recorrer cualquier rango en cualquier hoja.

Observe que al procedimiento se le pasan dos valores directamente, recuerde, y esto es quizás lo más habitual, que
también pueden pasarse variables, por ejemplo.

Sub Ejemplo_45
.
Dim Hoja As String
Dim Casilla_Inicial As String
Hoja = InputBox("En que hoja está la base de datos : ", "Entrar Nombre de Hoja")
Casilla_Inicial = InputBox("En que casilla comienza la base de datos","Casilla Inicial")
' Observe que los parámetros son dos variables cuyo valor se ha entrado desde teclado en
' las dos instrucciones InputBox anteriores.
Call Saltar_Celdas_Llenas(Hoja, Casilla_Inicial)
End Sub

Variables locales y variables Globales.

El ámbito de una variable declarada dentro de una función es la propia función, es decir no podrá utilizares fuera de dicha
función. Así, el siguiente programa que debería sumar las cinco filas siguientes a partir de la casilla activa y guardar el resultado en la sexta es incorrecto.

Sub Alguna_Cosa()
Call Sumar_Cinco_Siguientes
ActiveCell.Offset(6,0).Value = Suma
End Sub
Sub Sumar_Cinco_Siguientes()
Dim i As Integer
Dim Suma As Single
Suma=0
For i=1 To 5
Suma = Suma+ActiveCell.Offset(i,0).Value
Next i
End Sub

Es incorrecto porque tanto las variable i como la variable Suma están declaradas dentro del procedimiento Sumar_Cinco_Siguientes consecuentemente, su ámbito de acción es este procedimiento. Por tanto, la instrucción ActiveCell.Offset(6,0).Value = Suma del procedimiento Alguna_Cosa, generaría un error (con Option Explicit activado) ya que la variable Suma no está declarado dentro de él. Si piensa en declarar la variable Suma dentro del procedimiento Hacer_Algo, no solucionará nada porque esta será local a dicho procedimiento, en este caso tendría dos variables llamadas Suma pero cada una de ellas local a su propio procedimient o y consecuentemente con el ámbito de acción restringido a ellos.

Una solución, que a nosotros no nos gusta, seria declarar suma como variable global. Una variable global se declara fuera de todos los procedimientos y es reconocida por todos los procedimientos del módulo,

Option Explicit
' Suma es una variable global reconocida por todos los procedimientos del módulo.
Dim Suma As Single
Sub Alguna_Cosa()
Call Sumar_Cinco_Siguientes
ActiveCell.Offset(6,0).Value = Suma
End Sub
Sub Sumar_Cinco_Siguientes()
Dim i As Integer
Suma=0
For i=1 To 5
Suma = Suma+ActiveCell.Offset(i,0).Value
Next i
End Sub

Las variables globales son perfectas en cierta ocasiones, para este caso seria mejor declarar Suma en la función
Hacer_Algo y pasarla como parámetro al procedimiento Sumar_Cinco_Siguientes.
Sub Alguna_Cosa()
Dim Suma As Single
' Llamada a la función Sumar_Cinco_Siguientes pasándole la variable Suma
Call Sumar_Cinco_Siguientes(Suma)
ActiveCell.Offset(6,0).Value = Suma
End Sub
Sub Sumar_Cinco_Siguientes(S As Single)
Dim i As Integer
Suma=0
For i=1 To 5
S = S+ActiveCell.Offset(i,0).Value
Next i
End Sub

Esto le funcionaria porque la variable parámetro S (y se le ha cambiado el nombre adrede) de Sumar_Cinco_Siguientes es la variable Suma declarada en Hacer_Algo. Funcionará porque en Visual Basic, a menos que se indique lo contrario, el paso de parámetros es por referencia, vea la siguiente sección.

Paso por referencia y paso por valor.

No entraremos en detalles sobre como funciona el paso de parámetros por valor y el paso de parámetros por referencia, sólo indicaremos que en el :

a) paso por valor, la variable parámetro del procedimiento, recibe el valor de la variable (o directamente el valor) de su parámetro correspondiente de la instrucción de llamada y

b) paso por referencia, la variable parámetro del procedimiento, es la misma que su parámetro correspondiente de la instrucción de llamada, es decir, la declarada en el procedimiento desde el que se hace la llamada.

Por defecto, y siempre que en la instrucción de llamada se utilicen variables, las llamadas son por referencia. Si desea que el paso de parámetros sea por valor, debe anteponer a la variable parámetro la palabra reservada ByVal, por ejemplo,

Aunque lo elegante y efectivo por razones de memoria seria pasar siempre que sea posible por valor, es poco habitual que así se haga en Visual Basic, seguramente esto ocurre por comodidad. Como suponemos que hará como la mayoría, es decir, pasar por referencia, tenga cuidado con los (indeseables) efectos laterales.

Ejemplo Efecto_Lateral.
Antes de copiar el programa, active una hoja en blanco y ponga valores del 1 al 15 distribuidos de la forma siguiente, en el rango A1:A5 valores del 1 al 5, en el rango B1:B5 valores del 6 al 10, en el rango C1:C5 valores del 11 al 15.

El siguiente programa debe recorrer cada una de tres las columnas de valores, sumarlos y poner el resultado en las filas 6 de cada columna. Entonces, según los valores que ha entrado en cada una de las columnas, cuando haya acabado la ejecución del programa debe haber los siguientes resultados, A6 = 15, B6=40, C6=65.

Para llevar a cabo la suma de los valores de cada columna se llama a la función Recorrer_Sumar tres veces, una para cada columna, esta función recibe en el parámetro F el valor de la fila donde debe empezar a sumar, sobre el parámetro C el valor de la columna a sumar y sobre el parámetro Q la cantidad de filas que ha de recorrer.

El programa utiliza la propiedad Cells para referenciar las filas y columnas de los rangos. Observe atentamente los valores que irá cogiendo la variable Fila ya que esta será la que sufra el efecto lateral.

Sub Efecto_Lateral()
Dim Fila As Integer
Fila = 1
Call Recorrer_Sumar(Fila, 1,5) ' Columna A
Call Recorrer_Sumar(Fila, 2,5) ' Columna B
Call Recorrer_Sumar(Fila, 3,5) ' Columna C
End Sub
Sub Recorrer_Sumar(F As Integer, C As Integer, Q As Integer)
Dim i As Integer
Dim Total As Integer
Total = 0
For i =1 To Q
Total = Total + ActiveSheet.Cells(F, C).Value
F=F+1 ' OJO con esta asignación, recuerde que F es la variable Fila declarada en
' el procedimiento Efecto_Lateral
Next i
ActiveSheet.Cells(F, C) = Total
End Sub

Cuando ejecute el programa se producirá la salida siguiente, en A6 habrá un 15, hasta aquí todo correcto, pero observe que en la segunda columna aparece un 0 en B12 y en la tercera columna aparece un 0 en C18, veamos que ha pasado.

La primera vez que se llama la función, la variable F vale 1 ya que este es el valor que tiene su parámetro correspondiente (Fila) en la instrucción Call.

Observe que F se va incrementando una unidad a cada paso de bucle For, RECUERDE que F es realmente la variable Fila declarada en el procedimiento Efecto_Lateral, por tanto cuando finaliza el procedimiento Recorrer_Sumar y vuelve el control al procedimiento Efecto_Lateral Fila vale 6, y este es el valor que se pasará a Recorrer_Suma la segunda vez que se llama, a partir de ahí todo irá mal ya que se empezará el recorrido de filas por la 6.

Una de las soluciones a este problema para hacer que cada vez que se llame Recorrer_Sumar la variable F reciba el valor 1, es utilizar un paso por valor, es decir que F reciba el valor de Fila, no que sea la variable Fila, observe que entonces, si
F no es la variable Fila, cuando incremente F no se incrementará Fila, esta siempre conservará el valor 1.

Para hacer que F sea un parámetro por valor, simplemente ponga la palabra ByVal antes de F en la declaración del procedimiento.

Insistimos de nuevo en que tenga cuidado con estas cosas. Al menos ahora ya está sobre aviso, cuando un programa no haga lo que ha previsto una de las cosas que deberá repasar es el paso de parámetros a los procedimientos.

** Para finalizar, observe que en muchas ocasiones le hemos indicado que en el paso por referencia la variable del procedimiento llamado es la variable declarada en el procedimiento que llama. En este último ejemplo, le hemos dicho que F era la variable Fila, pues bien, esto no es cierto Fila es una variable y F es otra variable, ahora es lógico que se pregunte por qué entonces F actúa como si fuera Fila, este es un tema que no entra en el ámbito de este manual, si alguna vez programa en C y llega al tema de los punteros entenderá que es lo que sucede realmente en el paso por parámetro y en el paso por valor. Si ya conoce los punteros de C o Pascal entonces ya habrá intuido que el paso por valor en nuestro ejemplo equivaldría a,

Recorrer_Fila(F, C, Q);
void Recorrer_Fila(int F, int C, int Q)
Y un paso por referencia a
Recorrer_Fila(&F, C, Q);
Void Recorrer_Fila(int *F, int C, int Q)

Funciones.

Una función es lo mismo que un procedimiento con la salvedad que este devuelve un valor al procedimiento o función que lo llama. Vea el siguiente ejemplo, es una función muy sencilla ya que simplemente suma dos números y devuelve el resultado.

Ejemplo 46.
Función que devuelve la suma de dos valores que se le pasan como parámetros.

Sub Ejemplo_46()
Dim x As Integer
Dim n1 As Integer, n2 As Integer
X = Suma(5, 5)
n1= Val ( InputBox("Entrar un número : ", "Entrada"))
n2= Val ( InputBox("Entrar otro número : ", "Entrada"))
X= suma(n1,n2)
ActiveCell.Value = Suma(ActiveSheet.Range("A1").Value , ActiveSheet.Range("A2").Value)
X = Suma(5, 4) + Suma (n1, n2)
End Sub

Function Suma(V1 As Integer, V2 As Integer) As Integer
Dim Total As Integer
Total = V1 + V2
Suma = Total
End Function

Observe la sintaxis de la cabecera de función,
Function Suma(V1 As Integer, V2 As Integer) As Integer

La estructura general seria, Function Nombre_Funcion(par1 As Tipo, par2 As Tipo,..., parN As Tipo) As Tipo.

La sintaxis es similar a la cabecera de un procedimiento, sólo que una función tiene tipo, esto tiene su lógica, ya que una función devuelve un valor, ese valor será de un tipo determinado. Así, en nuestro ejemplo de Function Suma, esta función es de tipo Integer, o dicho de otra manera, la función ejecuta sus sentencias y devuelve un valor hacia el procedimiento o la función que la llamó, el valor devuelto se establece igualando el nombre de la función a algo,
Nombre_Función = ....

Observe también la sintaxis de la llamada a la función, en el ejemplo hemos utilizado unas cuantas formas de llamarla, lo que debe tener siempre presente es que en cualquier expresión aritmética o de cálculo, el ordenador realiza un mínimo de dos operaciones, una de cálculo y otra de asignación.

Por ejemplo, A= B+C El ordenador primero calcula el resultado de sumar B+C luego asigna ese resultado a la variable A. En cualquier llamada a una función, cojamos por caso, X= suma(n1,n2) Primero se ejecutan todas las sentencias de la función Suma, luego se asigna el cálculo de la función a la variable X. De otro vistazo a la función de ejemplo y vea lo que realiza cada sentencia en la que se llama a la función Suma.

Veamos a continuación unos cuantos ejemplos de funciones. Antes recordarle que todo lo referente a parámetros por valor y referencia, variables locales y globales, etc. que estudiamos en los procedimientos es lo mismo para las funciones.

Función que devuelve la dirección de la primera celda vacía de un rango. La función es de tipo String ya que devuelve la casilla en la forma "FilaColumna ", por ejemplo "A10". Utilizaremos la propiedad Address del objeto range, esta propiedad devuelve un string que contiene la referencia "FilaColumna" de una casilla o rango de casillas. En el caso de un rango devuelve,

' Función Casilla_Vacia de Tipo String
' Sirve para Recorrer las filas de una columna hasta encontrar una vacía.
' Parámetros :
' Casilla_Inicio : Casilla donde debe empezar a buscar.
' Devuelve Un string que contiene la referencia de la primera casilla

Function Casilla_Vacia(Casilla_Inicio As String) As String
ActiveSheet.Range(Casilla_Inicio).Activate
Do While Not IsEmpty(ActiveCell)
ActiveCell.Offset(1, 0).Activate
Loop
Casilla_Vacia = ActiveCell.Address
End Function

Similar al anterior. Es la típica búsqueda secuencial de un valor en un rango de casillas, en esta función solo se avanzará a través de una fila. La función devuelve la dirección (address) de la casilla donde está el valor buscado, en caso que el valor no esté en el rango de filas, devuelve una cadena vacía ("").

Dim Casilla As String
Casilla = Buscar_Valor("A1", 25)
' Si valor no encontrado
If Casilla = "" Then
Else 'Valor encontrado
End if
End Sub

' Función Buscar de Tipo String
' Sirve para Recorrer las filas de una columna hasta encontrar el valor buscado o una de vacía.
' Parámetros :
' Casilla_Inicial : Casilla donde debe empezar a buscar.
' Valor_Buscado : Valor que se debe encontrar
' Devuelve Un string que contiene la referencia de la casilla donde se ha encontrado el valor.
' También puede devolver "" en caso que el valor buscado no esté.

Function Buscar(Casilla_Inicial As String, Valor_Buscado As Integer) As String
ActiveSheet.Range(Casilla_Inicial).Activate
' Mientras casilla no vacía Y valor de casilla diferente al buscado
Do While Not IsEmpty(ActiveCell) And ActiveCell.Value <> Valor_Buscado
ActiveCell.Offset(1, 0).Activate
Loop
' Si la casilla donde se ha detenido la búsqueda NO ESTÁ VACÍA es que se ha encontrado
'el valor.
If Not IsEmpty(ActiveCell) Then
Buscar = ActiveCell.Address ' Devolver la casilla donde se ha encontrado el valor
Else ' La casilla está vacía, NO se ha encontrado el valor buscado
Buscar="" ' Devolver una cadema vacía
End if
End Function

Similar al anterior. Búsqueda secuencial de un valor en un rango de casillas, en esta función se avanzará a través de filas y columnas. La función devuelve la dirección (address) de la casilla donde está el valor buscado, en caso que el valor no esté en el rango, devuelve una cadena vacía ("").

Dim Casilla As String
Casilla = Buscar_Valor("A1", 25)
If Casilla = "" Then
Else
End if
End Sub
Function Buscar(Casilla_Inicial As String, Valor_Buscado As Integer) As String
Dim Incremento_Columna As Integer
Dim Continuar As Boolean
ActiveSheet.Range(Casilla_Inicial).Activate
Continuar = True
Do While Continuar
Incremento_Columna = 0
' Buscar el valor por las columnas hasta encontrarlo o encontrar una celda vacía.
Do While Not IsEmpty(ActiveCell.Offset(0, Incremento_Columna) And
ActiveCell. Offset(0, Incremento_Columna.Value <> Valor_Buscado
' Siguiente columna
Incremento_Columna = Incremento_Columna + 1
Loop
' Si no está vacía la casilla entonces parar la búsqueda, se ha encontrado el valor
If Not IsEmpty(ActiveCell.OffSet(0, Incremento_Columna)) Then
Continuar=False
Else ' La casilla está vacía, no se ha encontrado el valor
ActiveCell.Offset(1, 0).Activate ' Saltar a una nueva fila
If IsEmpty(ActiveCell) Then ' Si la casilla de la nueva fila está vacía
Continuar=False ' Parar la búsqueda, no hay más casilla a recorrer
End if
End if
Loop
' Si la casilla donde se ha detenido la búsqueda NO ESTÁ VACÍA es que se ha encontrado
'el valor.
If Not IsEmpty(ActiveCell) Then
Buscar = ActiveCell(0, Incremento_Columna).Address ' Devolver la casilla donde se
'ha encontrado el valor
Else ' La casilla está vacía, NO se ha encontrado el valor buscado
Buscar="" ' Devolver una cadema vacía
End if
End Function

Puede anteponer la cláusula private a todos los procedimientos y funciones que sean llamados sólo desde el mismo módulo, es una forma de ahorrar memoria y hacer que el programa corra un poco más rápido. Si necesita llamar un procedimiento o función desde otro módulo, nunca debe precederlo por la cláusula private, recuerde que esta cláusula restringe el ámbito de utilización de un procedimiento a su propio módulo. Supongamos el ejemplo siguiente.

' Módulo 2
Sub Procedimiento_de_modulo2
' Esto es correcto. Llama al procedimiento General definido en Módulo1
Call General
' Esto no es correcto. Llama al procedimiento Privado definido en Módulo 1, este
' procedimiento va precedido pro la cláusula Private, por tanto sólo puede ser llamado
' desde procedimientos de su propio módulo
Call Privado
End Sub

Vamos a ver a continuación tres ejemplos más sobre funciones. Es importante que los cree en un libro de trabajo nuevo y los ponga en un mismo módulo, al final del capítulo utilizaremos las opciones de exportar e importar módulos de procedimientos y funciones. En todos los ejemplos verá el procedimiento Procedimiento_Llamador, es para mostrar de que forma se debe llamar al procedimiento o función. Los procedimientos implementados son, por llamarlo de alguna manera, de tipo general, es decir, son procedimientos que podrá utilizar en muchas aplicaciones.

Procedimiento que abre un cuador MsgBox y muestra el texto que se le paso como parámetro.

Sub Procedimiento_Llamador()
Call mAviso("Esto es el mensaje de aviso", "Esto es el Título")
End Sub
' Procedimiento mAviso
' Función Mostrar el cuadro de función MsgBox, con el icono información y el botón OK (Aceptar).
' Se utiliza para mostrar avisos.
' Parámetros:
' Texto = Texto que muestra el cuadro
' Titulo = Título del cuadro
'
Sub mAviso(Texto As String, Titulo As String)
MsgBox Prompt:=Texto, Buttons:=vbOKOnly + vbInformation, Title:=Titulo
End Sub

Función tipo range que devuelve un rango. Observe como la función se iguala a una variable tipo Range, recuerde que con esta variable podrá acceder a todas las propiedades e invocar todos los métodos propios de los objetos Range.

En este ejemplo en concreto se utilizan las variables para Copiar un grupo de celdas de un rango hacia otro, se utilizan los métodos Copy y Paste del objeto Range.

Sub Procedimiento_Llamador()
Dim Rango_Origen As Range
Dim Rango_Destino As Range
Set Rango_Origen=Coger_Rango(A1,5,5)
Rango_Origen.Copy
Set Rango_Destino=Coger_Rango(G1,5,5)
Rango_Destino.Paste PasteSpecial:=xlPasteAll
End Sub
' Función que devuelve un rango a una variable de este tipo
' Parámetros
' Casilla = casilla inicial del rango
' Filas = número' de filas
' Columnas = número de columnas del rango

Function Coger_Rango(Casilla As String, Filas As Integer, Columnas As Integer) As Range
Dim Casilla_Final As String
ActiveSheet.Range(Casilla).Activate
ActiveCell.Cells(Filas, Columnas).Activate
Casilla_Final = ActiveCell.Address
ActiveSheet.Range(Casilla & ":" & Casilla_Final).Select
Set Coger_Rango = ActiveSheet.Range(Casilla & ":" & Casilla_FInal)
End Function

Función para comprobar el tipo de datos. Es una función de comprobación que se puede utilizar para validar los datos que se entran desde un cuadro InputBox o desde los cuadros de texto de formularios. La función es de tipo Booleano, devuelve True (cierto) o False en función de si el dato pasado es correcto. En esta función se evalúan sólo datos numéricos y datos tipo Fecha, puede ampliarla para que se comprueben más tipos.

Sub Procedimiento_Llamador()
Dim Cantidad As Integer
Dim Fecha As Date
Dim Datos As String
Datos = InputBox("Entrar una Cantidad : ", "Entrar")
If Not Comprobar_Tipo(Datos,"N") Then
mAviso("Los datos introducido no son numéricos", "Error")
Else
Cantidad = Val(Datos)
End If
Datos=InputBox("Entrar Fecha","Entrar")
If Not Comprobar_Tipo(Datos,"F") Then
mAviso("Los fecha introducida no es correcta", "Error")
Else
Fecha = Val(Datos)
End If
End Sub
' Función que evalúa si el tipo de datos que se le pasan son correctos o no. Si son correctos devuelve
' TRUE , en caso contrario devuelve FALSE
' Parámetros
' Valor =valor que se debe comprobar, de tipo String
' Tipo = tipo a comprobar, "N" --> Numérico, "F", tipo fecha
Function Comprobar_Tipo(Valor As String, Tipo As String) As Boolean
Dim Valido As Boolean
Valido = True
Select Case Tipo
' Comprueba si es un valor numérico válido
Case "N"
If Not IsNumeric(Valor) Then
Valido = False
End If
' Comprueba si es un valor fecha válido
Case "F"
If Not IsDate(Valor) Then
Valido = False
End If
End Select
Comprobar_Tipo = Valido
End Function

Importar y Exportar módulos.

Los últimos tres ejemplos que hemos visto, como le hemos indicado, son procedimientos que pueden ser utilizados en multitud de ocasiones o situaciones, seria interesante tenerlos disponibles en cualquiera de las hojas que confeccionemos.

Podría pensar en utilizar las opciones de copiar y pegar para pasar procedimientos de una hoja a otra, es un método totalmente válido y efectivo, pero le proponemos a continuación otro método más "profesional", por llamarlo de otra manera, e igual de efectivo. Este método consiste en guardar los procedimientos de un módulo en un archivo aparte, es decir, independiente de cualquier hoja de cálculo, luego, cuando en una nueva hoja necesite estas funciones, solo deberá importar este archivo para incorporarlo.

2. Active opción de la barra de menús Archivo/ Exportar archivo. Aparece un cuadro de diálogo.

3. En cuadro de edición Nombre de Archivo, teclee el nombre para el archivo donde se guardará el módulo, por ejemplo "General.Bas", observe que .BAS es la extensión de estos archivos.

Si está siguiendo el ejemplo, cierre todos los archivos de Excel y abra uno nuevo.

2. Active opción de la barra de menús Archivo/ Importar Archivo. Aparece un cuadro de diálogo.

3. Seleccione en la lista Buscar en: la carpeta donde tiene ubicado el archivo a importar (la carpeta donde está General.Bas si está siguiendo el ejemplo).

4. Una vez localizada la carpeta, seleccione el archivo a importar (General.Bas en el ejemplo) y pulse sobre Abrir.

Observe como en la ventana de proyecto se ha incorporado un nuevo módulo que contiene todos los procedimientos y
funciones del archivo importado.

Terminamos aquí el tema de procedimientos y funciones, déjenos insistir de nuevo en que es muy importante que construya sus programas utilizando todas las ventajas que le ofrece la programación modular. Como último consejo, agrupe todas las funciones que usted considere de utilización general en uno o dos módulos y luego utilice las opciones de importación y exportación para incorporarlos a sus programas.

Aplicaciones en Visual Basic

Vocabulario

Aplicación o Programa: